# Guía del programador de &kturtle; &logo;

Ésta es la guía de referencia para el programador de &kturtle; &logo;. En este capítulo comenzaremos introduciendo brevemente los diferentes tipos de instrucciones. A continuación, explicaremos las órdenes una a una. Más adelante, nos referiremos a las variables, los operadores matemáticos, los condicionales y las estructuras de control. Finalmente, aprenderemos a crear nuestras propias funciones, mediante la orden aprender.

## Los diferentes tipos de instrucciones

Como cualquier otro lenguaje, LOGO tiene diferentes tipos de palabras y símbolos. Aquí se explican brevemente las características de los distintos grupos y las diferencias existentes entre ellos.

### Órdenes

Las órdenes nos permiten pedirle a &kturtle; que realice una acción determinada. Algunas órdenes requieren alguna entrada, mientras que otras devuelven una salida.

    # avanzar es una orden que necesita una entrada, en este caso el número 100:
    avanzar 100

Podemos ver una descripción detallada de todas las órdenes que &kturtle; soporta aquí.

### Números

Seguramente ya conocerá bastante acerca de los números. La forma en la cual utilizaremos los números en &kturtle; no es muy diferente de como lo hacemos en el habla o las matemáticas.

Tenemos los llamados números naturales: `0`, `1`, `2`, `3`, `4`, `5`, etc. Los enteros negativos: `-1`, `-2`, `-3`, etc. Y los números con decimales `0.1`, `3.14`, `33.3333`, `-5.05`, `-1.0`.

Los números pueden utilizarse en cálculos matemáticos y condicionales. Y también pueden ponerse dentro de variables.

Los números se resaltan con azul en el editor de código.

### Cadenas

Comenzaremos con un ejemplo:

    escribir "Hola, soy una cadena."

En nuestro ejemplo, `escribir` es una orden. Esta orden toma como parámetro de entrada una cadena: "Hola, soy una cadena.". Las comienzan y terminan con el símbolo `"`, de forma que con estas marcas &kturtle; sabe que es una cadena.

Las cadenas pueden utilizarse dentro de variables. Pero no es posible utilizarlas en cálculos matemáticos y condicionales.

Las cadenas se resaltan con rojo oscuro en el editor de código.

### Nombres

A medida que utilicemos el lenguaje de programación &logo;, iremos generando nuestras propias estructuras. Con frecuencia, haremos uso de las variables, y en muchos casos invocaremos la orden aprender para crear nuestras nuevas funciones. Al crear una variable o una nueva función con aprender, tendremos que darle un nombre a nuestra nueva estructura.

Así, podremos utilizar cualquier nombre, siempre y cuando no este siendo ya utilizado por alguna orden. Por ejemplo, no es posible utilizar el nombre avanzar por ser este el nombre de una orden KTurtle.

    # Si intentáramos hacer lo siguiente, obtendríamos mensaje
    # de error: avanzar = 20

    # Ésto en cambio si funcionaría
    avanzar 20

Todo nombre debe comenzar con una letra. A partir de allí, puede contener tanto letras, como números o símbolos de subrayado (_).

Por favor lea la documentación de las variables y de la orden aprender para obtener una explicación más detallada y más ejemplos.

### Asignaciones

Las asignaciones se realizan con el símbolo `=`. En los lenguajes de programación entendemos el símbolo `=` diciendo que tal variable toma el valor de, y no diciendo que tal variable es igual a. Decir que una variable es igual a, es más apropiado para el símbolo `==` que no es una asignación sino un condicional.

Las asignaciones se utilizan por lo general por dos motivos: (1) para dar contenido a una variable, y (2) para modificar el contenido de una variable. Por ejemplo:

    x = 10
    # la variable x toma el valor del número 10
    W = "Mi edad es: "
    # la variable W toma ahora el valor de la cadena "Mi edad es: "
    # Ahora, escribimos el valor de ambas variables en el área de dibujo.
    escribir W + x

Consulte la sección variables para ver más ejemplos.

### Símbolos matemáticos

&kturtle; soporta todas las operaciones matemáticas básicas: suma (`+`), resta (`-`), multiplicación (`*`), división (`/`) y los parentesis `(` y `)`.

Para obtener una explicación más completa, consulte la sección matemática.

### Condicionales

Podemos establecer condiciones simples en las cuales la respuesta será simplemente «verdadero» o «falso».

El uso de los condicionales se explica detalladamente en la sección condicionales.

### Operadores lógicos

Los condicionales pueden combinarse mediante los llamados «operadores lógicos». Los operadores lógicos están representados por `y`, `o` y `no`.

El uso de los operadores lógicos se explica detalladamente en la sección condicionales.

### Comentarios

Los comentarios son líneas que comienzan con `#`. Por ejemplo:

    # Esto es un comentario
    escribir "Esto no es un comentario"
    # Es decir, la línea anterior no era un comentario, pero la próxima lo será:
    # escribir "Esto no se mostrará porque es un comentario."

La utilidad de los comentarios reside tanto en la posibilidad de dar una breve explicación acerca del código, como en la de apartar momentáneamente ciertas líneas de la ejecución, sin tener que borrarlas.

Las líneas comentadas se resaltan en amarillo oscuro en el editor de código.

## Órdenes

Las órdenes nos permiten pedirle a &kturtle; que realice una acción determinada. Algunas órdenes requieren una entrada, mientras que otros devuelven una salida. En esta sección explicaremos todas las órdenes de &kturtle;. Todas las órdenes de las que hablaremos en esta sección aparecerán resaltadas en el editor de código en verde oscuro, de forma que sea más fácil distinguirlas.

### Mover la tortuga

Disponemos de varias órdenes que nos permitirán desplazar la tortuga a lo largo y ancho de la pantalla.

#### avanzar (avz)

avanzar

-     avanzar X

  `avanzar` hace avanzar la tortuga X pixels. Cuando la pluma esté abajo, la tortuga dejará un trazo. `avanzar` puede abreviarse como `avz`

#### retroceder (rtd)

retroceder

-     retroceder X

  `retroceder` hace retroceder la tortuga X pixels. Cuando la pluma esté abajo, la tortuga dejará un trazo. `retroceder` puede abreviarse como `rtd`.

#### izquierda (izq)

izquierda

-     izquierda X

  `izquierda` le pide a la tortuga que rote X grados hacia la izquierda. `izquierda` puede abreviarse como `izq`.

#### derecha (dch)

derecha

-     derecha X

  `derecha` le pide a la tortuga que rote X grados hacia la derecha. `derecha` puede abreviarse como `dch`.

#### dirección (dir)

dirección

-     dirección X

  `dirección` determina el ángulo de dirección de la tortuga medido en X grados, contando desde cero. Es decir, que no es relativo a la dirección anterior de la tortuga. `dirección` se puede abreviar como `dir`.

#### centro

centro

-     centro

      centro

  desplaza la tortuga al centro del área de dibujo.

#### ir

ir

-     ir X, Y

  `ir` le indica a la tortuga que debe ir al lugar X, Y del área de dibujo. Esto significa, contando a partir del la esquina superior izquierda, X pixels hacia la derecha e Y pixelshacia abajo. Se debe aclarar que al utilizar la orden `ir`, la tortuga no dibujará una línea en su trayectoría.

#### irx

irx

-     irx X

  `irx` hace que la tortuga se desplace a X pixels contando desde la izquierda del área de dibujo, manteniéndose a la misma altura.

#### iry

iry

-     iry Y

  `irx` hace que la tortuga se desplace a Y pixels contando desde la parte superior del área de dibujo, manteniéndose a la misma altura.

### La tortuga tiene una pluma

La tortuga tiene una pluma que dibuja una línea cuando se mueve. Existen algunas órdenes que controlan esta pluma. En esta sección, explicaremos estas órdenes.

#### levantarpluma (lpl)

levantarpluma

-     levantarpluma

  `levantarpluma` levanta la pluma del área de dibujo. Cuando la pluma está «arriba» la tortuga no trazará ninguna línea a su paso. La orden `levantarpluma` puede también abreviarse como `lpl`.

#### bajarpluma (bpl)

bajarpluma

-     bajarpluma

  `bajarpluma` presiona la pluma sobre el área de dibujo. Cuando la pluma está «abajo» la tortuga trazará una línea a su paso. La orden `bajarpluma` puede también abreviarse `bpl`.

#### grosorpluma (gpl)

grosorpluma

-     grosorpluma X

  `grosorpluma` determina el grosor de la línea trazada por la tortuga en X pixels.La orden `grosorpluma` puede abreviarse como `gpl`.

#### colorpluma (cpl)

colorpluma

-     colorpluma R, V, A

  `colorpluma` determina el color de la línea trazada por la tortuga. La orden `colorpluma` toma una combinación RGB como parámetro de entrada. `colorpluma` puede abreviarse como `cpl`.

### Órdenes que controlan el área de dibujo

Existen varias órdenes que podremos utilizar para controlar el área de dibujo.

#### tamañolienzo (tad)

tamañolienzo

-     tamañolienzo X, Y

  Con la orden `tamañolienzo` podemos redimensionar el área de dibujo. Toma dos parámetros de entrada, X e Y, los cuales representan respectivamente el ancho y el alto en pixels. La orden `tamañolienzo` puede abreviarse como `tad`.

#### colorlienzo (cad)

colorlienzo

-     colorlienzo R, V, A

  `colorlienzo` define el color del área de dibujo. `colorlienzo` toma una combinación RGB como parámetro de entrada. `colorlienzo` puede abreviarse como `cad`.

#### envolver

envolver

-     envolver

  La orden `envolver` nos permite «activar» la envoltura (wrapping) del área de dibujo. En el glosario encontraremos más información acerca del concepto wrapping.

#### desenvolver

desenvolver

-     desenvolver

  La orden `desenvolver` nos permite «desactivar» la envoltura (wrapping) del área de dibujo. En el glosario encontraremos más información acerca del concepto wrapping.

### Órdenes para la limpieza

Existen dos órdenes para borrar el área de dibujo después de que la haya ensuciado.

#### limpiar (lmp)

limpiar

-     limpiar

  Con `limpiar` dejaremos el área de dibujo totalmente limpia. Sin embargo, todas las demás condiciones como ángulo de la tortuga, color del área de dibujo, etc. permanecerán intactas. La orden `limpiar` puede abreviarse como `lmp`.

#### restaurar

restaurar

-     restaurar

  `restaurar` limpia todo el entorno, a diferencia de `limpiar` que solo deja en limpio el área de dibujo. Después de `restaurar`, todo vuelve al estado en el que &kturtle; estaba al iniciarse: la tortuga se posiciona en el medio del área de dibujo, el color de fondo es blanco, y el color de línea negro.

### La tortuga es una imagen móvil

Para quien no sepa lo que es una imagen móvil, comenzaremos con una breve explicación: las imágenes móviles son pequeñas figuras que pueden moverse alrededor de la pantalla, como las que vemos en los juegos de ordenador. Entonces, nuestra tortuga es una imagen móvil. Obtendremos más información en el glosario en imágenes móviles.

A continuación encontraremos una descripción detallada de todas las órdenes que podemos utilizar para manejar las imágenes móviles.

La versión actual de &kturtle; no soporta todavía el uso de otras imágenes móviles más allá de la tortuga. Pero esto puede cambiar en las próximas versiones.

#### Mostrar la tortuga

mostrartortuga (mt)

-     mostrartortuga

  `mostrartortuga` hace la tortuga visible después de haberla ocultado. Puede abreviarse la orden `mostrartortuga` como `mt`.

#### ocultartortuga (ot)

ocultartortuga

-     ocultartortuga

  `ocultartortuga` oculta la tortuga. Puede utilizarse si la tortuga no quedase bien dentro de nuestro dibujo.`ocultartortuga` puede abreviarse como `ot`.

### ¿La tortuga puede escribir?

La respuesta es «sí», la tortuga puede escribir cualquier cosa que le pida.

#### escribir

escribir

-     escribir X

  La orden `escribir` se utiliza para que la tortuga escriba algo sobre el área de dibujo. `escribir` acepta cadenas alfanuméricas como parámetro de entrada. Es posible concatenar los parámetros de `escribir` mediante el símbolo «+». Veamos el siguiente ejemplo:

      año = 2003
      autor = "Cies"
      escribir autor + "comenzó a trabajar en el proyecto KTurtle en el año" + año + "y todavía disfruta haciéndolo"

#### tamañofuente

tamañofuente

-     tamañofuente X

  `tamañofuente` determina el tamaño en pixelsde la tipografía utilizada por `escribir`. `tamañofuente` toma una entrada numérica. El tamaño ha de establecerse en pixels.

### Una orden que tira los dados por nosotros

Existe una orden que tira los dados por nosotros, se llama `aleatorio`, y es práctica para obtener resultados inesperados.

aleatorio

-     aleatorio X,Y

  `aleatorio` es una orden que toma dos parámetro de entrada, X e Y, y devuelve un número. La X y la Y representan respectivamente el mínimo y el máximo que podrá tomar el valor de salida. Dicho valor de salida es un número dentro de ese intervalo cerrado. Veamos aquí un pequeño ejemplo:

      repetir 500 [
        x = aleatorio 1,20
        avanzar x
        izquierda 10 - x
      ]

  Utilizando la orden `aleatorio` podemos agregar un poco de incertidumbre a nuestro programa.

### Entrada y salida mediante diálogos

Un diálogo es una ventana emergente que puede proporcionar alguna información o pedir que se le pasen datos. &kturtle; se encarga de los diálogos mediante `mensaje` y `pregunta`

#### mensaje

mensaje

-     mensaje X

  La orden `mensaje` toma una cadena alfanumérica como parámetro de entrada, generando un diálogo emergente que contiene la cadena dada.

      año = 2003
      autor = "Cies"
      escribir autor + "comenzó a trabajar en el proyecto KTurtle en el año" + año + "y todavía disfruta haciéndolo"

#### pregunta

pregunta

-     pregunta X

  `pregunta` toma una cadena como parámetro de entrada y nos muestra un diálogo emergente con el texto dado, tal como lo hace mensaje. Sin embargo, también muestra una casilla que permitirá al usuario introducir tantonúmeros como cadenas alfanuméricas y pueden ser guardados en una variable. Por ejemplo,

      entrada = pregunta "¿Cuál es tu edad?"
      salida = 2003 - in
      escribir "En 2003 tenías " + salida + " años."

  Cuando el usuario cancela el diálogo o no introduce nada, lavariable quedará vacía.

## Variables

Las variables son letras o cadenas de texto que pueden ser utilizadas por el programador para guardar información dentro de ellas. Las variables que contienen números son llamadas variables numéricas, las que contienen cadenas de texto se llaman variables alfanuméricas.

Las variables no utilizadas, están vacías. Por ejemplo:

    escribir N

No mostrará nada hasta que no declaremos a N. Si intentamos realizar operaciones matemáticas con variables no declaradas, obtendremos un error.

### Variables numéricas

Para comenzar, veamos un ejemplo

    x = 3
    escribir x

En la primera línea declaramos a `x` como una variable numérica que contiene el valor 3. En la segunda línea, se muestra el valor de `x` en el área de dibujo.

Observemos que si hubiéramos querido imprimir la letra «x», deberíamos haber escrito

    escribir "x"

Ahora veamos un ejemplo algo más complejo:

    A = 2004
    B = 25
    C = A + B

    # la próxima orden muestra "2029"
    escribir C
    retroceder 30
    # la próxima orden muestra "2004 más 25"
    escribir A + " más " + B
    retroceder 30
    # la próxima orden muestra "1979"
    escribir A - B

En las primeras dos líneas, se declaran las variables `A` y `B` y se les asigna los valores 2004 y 25. En la tercera línea se le asigna la operación `A + B` (2029) a la variable `C`. El resto del código consiste en 3 `escribir` y dos `retroceder 30`.

### Variables alfanuméricas

En general, en los lenguajes de programación, las cadenas de texto se encierran entre comillas. Así, en

    escribir "Hola programador"

la cadena esta encerrada entre comillas.

Las cadenas de texto pueden almacenarse en variables alfanuméricas. Las variables numéricas y alfanuméricas difieren en el tipo de contenido que almacenan (números y cadenas respectivamente) y a partir de allí en el tipo de operaciones que podemos realizar con ellas. De este modo, no podremos realizar operaciones aritméticas ni condicionales con variables alfanuméricas. Veamos ahora un ejemplo del uso de las cadenas de texto:

    x = "Hola "
    nombre = pregunta "¿Cuál es tu nombre?"
    escribir x + nombre + ", ¿Cómo estamos hoy?"

. En la primera línea asignamos la cadena «Hola » a la variable alfanumérica`x`. En la segunda, a la variable alfanumérica `nombre` se le asigna la salida de la orden `pregunta`. En la tercer línea el programa escribe una composición de las tres variables en el área de dibujo.

Este programa nos pide que introduzcamos un nombre. Entonces, por ejemplo, si escribimos «Fernanda», el programa nos responderá «Hola Fernanda, ¿Cómo estamos hoy?». Observemos que en nuestro código utilizamos el operador aritmético correspondiente a la adición (+). Éste es el único operador aritmético que podemos utilizar con cadenas de texto, y la función que cumple es la de unir dichas cadenas.

## ¿Puede la tortuga resolver operaciones matemáticas?

Sí, la tortuga de &kturtle; puede resolver operaciones matemáticas como sumar (+), restar (-), multiplicar (*) y dividir (/). Veamos un ejemplo en el que utilizamos todas ellas:

    a = 20 - 5
    b = 15 * 2
    c = 30 / 30
    d = 1 + 1
    escribir "a: "+a+", b: "+b+", c: "+c+", d: "+d

Así, asignamos valores númericos a las variables a, b, c, y d mediante el simbolo de asignación `=`.

Si queremos realizar un cálculo simple, bastará con algo similar a:

    escribir 2004-12

Ahora veamos un ejemplo en el cual utilizamos los paréntesis

    escribir ( ( 20 - 5 ) * 2 / 30 ) + 1

Así, las operaciones se agrupan entre paréntesis de modo que se van calculando en el orden establecido. En este ejemplo, primero se calculará 20 - 5, luego se multiplicará el resultado por dos y a eso se le dividirá por 30. Finalmente, al resultado obtenido anteriormente se le suma 1. El resultado final es 2.

## Establecer condiciones para obtener respuestas...

`si` y `mientras` son estructuras de control de las que hablaremos en la próxima sección. En esta sección utilizaremos la orden `si` para explicar los condicionales.

### Condicionales

Un ejemplo simple del uso de condicionales:

    x = 6
    si x > 5 [
      escribir "Hola"
    ]

En este ejemplo la condición es: `x > 5`. Si la condición se cumple (es verdadera), se ejecuta la parte del código que está entre corchetes. Los condicionales son una parte importante en los lenguajes de programación y generalmente se les utiliza en combinación con las estructuras de control como `si`. Todos los números y las variables numéricas pueden formar parte de condicionales.

A continuación podemos ver todos los condicionales:

### Tipos de condicionales

`a == b` | igual | La respuesta es «verdadera» si `a` es igual a `b`
`a != b` | distinto | La respuesta es «verdadera» si `a` no es igual a `b`
`a > b` | a es mayor que b | La respuesta es «verdadera» si `a` es es mayor que `b`
`a < b` | a es menor que b | La respuesta es «verdadera» si `a` es es menor que `b`
`a >= b` | a es mayor o igual que b | La respuesta es «verdadera» si `a` es es mayor o igual que `b`
`a <= b` | a es menor o igual que b | La respuesta es «verdadera» si `a` es es menor que `b`

Los condicionales se resaltan en azul claro en el editor de código.

### Operadores lógicos

Los operadores lógicos nos permiten agrupar varias condiciones en un único condicional.

    a = 1
    b = 5
    si (a < 5) y (b == 5) [
      escribir "Hola"
    ]

En este ejemplo, utilizamos al operador lógico `y` para agrupar dos condiciones (`a < 5`, `b == 5`). Si alguna de las dos condiciones agrupadas por el operador lógico `y` fuera «falsa», toda la sentencia resultaría «falsa». Así, el operador lógico `yy` requiere que ambas condiciones (tanto a izquierda como a derecha) sean «verdaderas» para que el condicional resulte verdadero. Además, debemos recordar que ambas condiciones deben estar encerradas entre paréntesis.

Aquí se nos presenta una visión esquemática. A continuación encontraremos una explicación más detallada:

### Operadores lógicos

`yy` | Ambos lados deben ser verdaderos para que la condición sea verdadera
`oo` | Si al menos una de las condiciones es verdadera, la sentencia es verdadera
`no` | Es un caso especial que solo funciona en condicionales. Lo que hace es cambiar «verdadero» por «falso» y «falso» por «verdadero». Dicho de otro modo, niega la condición original.

Los operadores lógicos se resaltan en morado en el editor de código.

#### yy

Cuando dos condiciones están agrupadas por el operador lógico `yy`, la sentencia debe ser verdadera a ambos lados del `yy` para que se considere verdadera. Por ejemplo:

    a = 1
    b = 5
    si ((a < 10) yy (b == 5)) yy (a < b) [
      escribir "Hola"
    ]

En este ejemplo se utilizan dos operadores lógicos. El primero, opera sobre las dos primeras condiciones que se encuentran entre paréntesis, y el segundo opera sobre la tercera condición y el resultado de las dos anteriores.

#### oo

Cuando dos condiciones están agrupadas por el operador lógico `oo`, la sentencia debe ser verdadera a alguno de los dos lados del `oo` para que se considere verdadera. Por ejemplo:

    a = 1
    b = 5
    si ((a < 10) oo (b == 5)) oo (a < b) [
      escribir "Hola"
    ]

Al igual que el ejemplo anterior, aquí se utilizan dos operadores lógicos. El primero, opera sobre las dos primeras condiciones que se encuentran entre paréntesis, y el segundo opera sobre la tercera condición y el resultado de las dos anteriores.

#### no

`no` es un caso especial de operador lógico, ya que opera solamente sobre una condición. El efecto que el operador lógico `no` tiene sobre la condición, es la de negarla.

    a = 1
    b = 5
    si no ((a < 10) yy (b == 5)) [
      escribir "Hola"
    ]
    sino
    [
      escribir "adios ;-)"
    ]

Observemos que la condición que se plantea es verdadera. Sin embargo, la presencia del operador de negación, hace que la sentencia resulte falsa por lo que nuestro programa imprimirá «adios».

## Estructuras de control

Las estructuras de control nos permiten, tal como su nombre lo indica, controlar la ejecución.

Las órdenes de ejecución se resaltan en verde oscuro y negrita. Los corchetes se resaltan en verde claro.

### Hagamos que la tortuga espere

Después de haber programado durante algún tiempo en &kturtle;, nos daremos cuenta de que, a veces, la tortuga va demasiado rápido. Con la orden esperar, podemos hacer que la tortuga se detenga durante una cantidad de tiempo determinada.

esperar

-     esperar X

  `esperar` hace que la tortuga espere X segundos.

      repetir 36 [
        avanzar 5
        derecha 10
        esperar 0.5
      ]

  Este código dibuja un círculo, pero la tortuga esperará medio segundo después de cada paso. Ésto da la impresión de que la tortuga se mueve lentamente por la pantalla.

### Ejecutar "si"

si

-     si condición [ ... ]

  El código entre corchetes solo se ejecutará `si` la condición es «verdadera». Podemos leer más acerca de lascondiciones en la sección condicionales de este manual.

      x = 6
      si x > 5 [
        escribir "x es mayor que cinco"
      ]

  En la primer línea, `x` toma el valor 6. En la segunda, se plantea la condición `x > 5`. Ya que esta condición se cumple, la estructura de control `sí` permitirá que el código entre corchetes se ejecute.

### El bucle "mientras"

mientras

-     mientras condición [ ... ]

  La estructura de control `mientras` actúa en forma similar a `si`. La diferencia es que `mientras` generará un bucle que repetirá la ejecución de código siempre que condición no sea «falsa».

      x = 1
      mientras x < 5 [
        avanzar 10
        esperar 1
        x = x + 1
      ]

  En la primer línea, `x` toma el valor 1. En la segunda, se plantea la condición `x < 5`. Ya que esta condición se cumple, la estructura de control `mientras` permitirá que el código entre corchetes se ejecute hasta que la condiciónse evalúe como «falsa». En este ejemplo, el código entre corchetes se ejecutará cuatro veces, ya que el valor de `x` se incrementa en 1 en cada iteración.

### En cualquier otro caso, en otras palabras "sino"

sino

-     Si condición [...] sino [...]

  `sino` puede utilizarse para controlar la ejecución de `si`. El código que se encuentra entre corchetes después de un `sino` solo se ejecutará si la condición planteada por el si «no se cumple (es falsa)».

      restaurar
      x = 4
      si x > 5 [
        escribir "x es mayor que cinco."
      ]
      sino
      [
        escribir "x es menor que seis."
      ]

  La condición pregunta si `x` es mayor que 5. Como `x` toma el valor 4 en la primera línea, la condición es «falsa». Ésto significa que el código entre corchetes después del `sino` se ejecutará.

### La estructura de control "para", un bucle que sabe contar

para

-     para punto inicial a punto final[ ... ]

  La estructura de control `para` es «un bucle que sabe contar», &ie;

      para x = 1 a 10 [
        escribir x * 7
        avanzar 15
      ]

  Cada vez que el código entre corchetes se ejecuta, la variable numérica `x` se incrementa en 1 hasta que el valor de `x` llega a 10. El código entre corchetes muestra el valor de `x` multiplicado por 7. Una vez que el código termine de ejecutarse, veremos la tabla del 7 en el área de dibujo.

## Crear sus propias funciones con «aprender»

`aprender` se utiliza para crear funciones personalizadas. La nueva función puede tanto tomar parámetros de entrada como devolver valores como salida. Veamos entonces como podemos crear nuestras propias funciones. Crearemos la función `círculo`:

    aprender círculo x [
      repetir 36 [
        avanzar x
        izquierda 10
      ]
    ]

Así, definimos el nombre de la función como `círculo`, y esperamos un parámetro de entrada numérico y ningún parámetro de salida. Ahora, podemos utilizar la función `círculo` en cualquier lugar de nuestro código. Veamos este ejemplo:

    aprender círculo X [
      repetir 36 [
        avanzar X
        izquierda 10
      ]
    ]

    ir 30,30
    círculo 20

    ir 40,40
    círculo 50

En el próximo ejemplo veremos como crear una función que devuelva un valor.

    restaurar

    aprender multiplicarPorSiMismo n [
      r = n * 1
      r = n * n
      devolver r
    ]
    i = pregunta "Introduzca un número:"
    escribir i + " multiplicado por si mismo es: " +multiplicarPorSiMismo  i

En este ejemplo, creamos una función llamada `multiplicarPorSiMismo`. Esta función pide que se introduzca un número. A continuación, lo multiplica por si mismo y devuelve el resultado con la orden `return`. La orden `devolver` es la forma que tenemos de decirle a una función que queremos que devuelva un valor determinado.